XIAO nRF52840で加速度センサデータを飛ばす(1)

 

加速度センサの計測結果をBLEで飛ばすっていう試み。XIAO nRF52840と秋月AE-ADXL367を使って。

XIAO nRF52840でなんかできんかなって雑な発想で秋月AE-ADXL367(https://akizukidenshi.com/catalog/g/g129428/)を購入。温度とか湿度とかをBLEで飛ばすのよりは加速度のほうがちょっと面白いかもなって。pinoutと結線はこのようにする。

データシートによるとINT2は出力だからn.c.でよくて、ADC_INはn.c.でいいぜって書いてあるのでn.c.で、VREG_OUTはパスコンつなげろって書いてあるけど、秋月のボード上に実装してあるようなのでさらにってことはないと思う。
では、ソフトを作っていくんだけど、ADXL367を制御するArduinoライブラリはなさそうなので、自力でデータシートと格闘しないといけない。まぁたったの全64ページ。格闘というほどではない。で、連続データ取得、INT１ピンにDataReadyをアクティブLowで出したい、ODRは12.5Hz(とりあえず)、測定レンジはフルスケール±4gってことにして、この辺をいじっていけばいいってのがわかる。

で、BLEほうは、Arduinoのexampleに入っているperipheral bleuartを使うことにする。っていうか完全にパクる。<--もうこのへんってデバイスが勝手にやっちゃうのが多すぎ。、、、全部知ろうとすることが無茶なくらい複雑な世の中になってきたのでしょうがないんだけど、複雑な心境ではある。とはいえまずは普通にADXL367を動かしてみる。

1. #include <SPI.h>
2. #define pinMOSI (10)
3. #define pinMISO (9)
4. #define pinSCK (8)
5. #define pinCS (7)
6. #define pinDRDY (6)
7. #define ADDRESS_INTMAP1_LOWER (0x2A)
8. #define ADDRESS_FILTER_CTL (0x2C)
9. #define ADDRESS_POWER_CTL (0x2D)
10. #define ADDRESS_STATUS (0x0B)
11. #define ADDRESS_XDATA_H (0x0E)
12. #define ADDRESS_XDATA_L (0x0F)
13. #define ADDRESS_YDATA_H (0x10)
14. #define ADDRESS_YDATA_L (0x11)
15. #define ADDRESS_ZDATA_H (0x12)
16. #define ADDRESS_ZDATA_L (0x13)
17. #define ADDRESS_SOFT_RESET (0x1F)
18. #define VALUE_INTMAP1_LOWER (0x81)
19. #define VALUE_FILTER_CTL (0x40)
20. #define VALUE_POWER_CTL (0x02)
21. #define VALUE_SOFT_RESET (0x52)
22. SPISettings mySPISettings=SPISettings(1000000,MSBFIRST,SPI_MODE0);
23. void SPI_writeRegister(uint8_t adr,uint8_t data){
24.     uint8_t txbuf[3];
25.     uint8_t rxbuf[3];
26.     txbuf[0]=0x0A;
27.     txbuf[1]=adr;
28.     txbuf[2]=data;
29.     digitalWrite(pinCS,LOW);
30.     delayMicroseconds(1);
31.     SPI.transfer(txbuf,rxbuf,3);
32.     delayMicroseconds(1000);
33.     digitalWrite(pinCS,HIGH);
34. }
35. uint8_t SPI_readRegister(uint8_t adr){
36.     uint8_t txbuf[3];
37.     uint8_t rxbuf[3];
38.     txbuf[0]=0x0B;
39.     txbuf[1]=adr;
40.     txbuf[2]=0x00;
41.     digitalWrite(pinCS,LOW);
42.     delayMicroseconds(1);
43.     SPI.transfer(txbuf,rxbuf,3);
44.     delayMicroseconds(1000);
45.     digitalWrite(pinCS,HIGH);
46.     return rxbuf[2];
47. }
48. volatile uint8_t drdy_detected;
49. void interruptHandler_pinDRDY(){
50.     drdy_detected=1;
51. }
52. void readStatusAndData(uint8_t* buf){
53.     buf[0]=SPI_readRegister(ADDRESS_STATUS);
54.     buf[1]=SPI_readRegister(ADDRESS_XDATA_H);
55.     buf[2]=SPI_readRegister(ADDRESS_XDATA_L);
56.     buf[3]=SPI_readRegister(ADDRESS_YDATA_H);
57.     buf[4]=SPI_readRegister(ADDRESS_YDATA_L);
58.     buf[5]=SPI_readRegister(ADDRESS_ZDATA_H);
59.     buf[6]=SPI_readRegister(ADDRESS_ZDATA_L);
60. }
61. const char char_array[]="0123456789ABCDEF";
62. void hex2chars(uint8_t src,char* tgt){
63.   tgt[0]=char_array[(src>>4)&0x0F];
64.   tgt[1]=char_array[(src>>0)&0x0F];
65. }
66. void bytes2chars(uint8_t n,char* strbuf,uint8_t* bytedata){
67.     uint8_t i;
68.     for(i=0;i<n;i++){
69.         hex2chars(bytedata[i],&strbuf[i*2]);
70.     }
71.     strbuf[n*2]='\0';
72. }
73.  
74. uint8_t buf[7];
75. char sendbuf[16];
76.  
77. void setup(){
78.     uint8_t temp;
79.     drdy_detected=0;
80.     pinMode(pinCS,OUTPUT);
81.     pinMode(pinMOSI,OUTPUT);
82.     pinMode(pinSCK,OUTPUT);
83.     pinMode(pinMISO,INPUT);
84.     digitalWrite(pinCS,HIGH);
85.     digitalWrite(pinMOSI,LOW);
86.     digitalWrite(pinSCK,LOW);
87.     pinMode(pinDRDY,INPUT_PULLUP);
88.     SPI.begin();
89.     SPI.beginTransaction(mySPISettings);
90.     delay(1);
91.     SPI_writeRegister(ADDRESS_SOFT_RESET,VALUE_SOFT_RESET);
92.     delay(1);
93.     temp=SPI_readRegister(ADDRESS_INTMAP1_LOWER);
94.     while(temp!=VALUE_INTMAP1_LOWER){
95.         SPI_writeRegister(ADDRESS_INTMAP1_LOWER,VALUE_INTMAP1_LOWER);
96.         delay(1);
97.         temp=SPI_readRegister(ADDRESS_INTMAP1_LOWER);
98.     }
99.     temp=SPI_readRegister(ADDRESS_FILTER_CTL);
100.     while(temp!=VALUE_FILTER_CTL){
101.         SPI_writeRegister(ADDRESS_FILTER_CTL,VALUE_FILTER_CTL);
102.         delay(1);
103.         temp=SPI_readRegister(ADDRESS_FILTER_CTL);
104.     }
105.     temp=SPI_readRegister(ADDRESS_POWER_CTL);
106.     while(temp!=VALUE_POWER_CTL){
107.         SPI_writeRegister(ADDRESS_POWER_CTL,VALUE_POWER_CTL);
108.         delay(1);
109.         temp=SPI_readRegister(ADDRESS_POWER_CTL);
110.     }
111.  
112.     delay(100);
113.     Serial.begin(115200);
114.     while(!Serial){delay(10);}
115.     Serial.println("=== AE-ADXL367 control example using XIAO nRF52840 ===");Serial.flush();
116.     buf[0]=SPI_readRegister(ADDRESS_INTMAP1_LOWER);
117.     buf[1]=SPI_readRegister(ADDRESS_FILTER_CTL);
118.     buf[2]=SPI_readRegister(ADDRESS_POWER_CTL);
119.     bytes2chars(3,sendbuf,buf);
120.     Serial.println(sendbuf);Serial.flush();
121.     readStatusAndData(buf);
122.     bytes2chars(7,sendbuf,buf);
123.     Serial.println(sendbuf);Serial.flush();
124.     readStatusAndData(buf);
125.     bytes2chars(7,sendbuf,buf);
126.     Serial.println(sendbuf);Serial.flush();
127.     attachInterrupt(digitalPinToInterrupt(pinDRDY),interruptHandler_pinDRDY,FALLING);
128. }
129.  
130. void loop(){
131.     if(drdy_detected){
132.         drdy_detected=0;
133.         readStatusAndData(buf);
134.         bytes2chars(7,sendbuf,buf);
135.         Serial.println(sendbuf);Serial.flush();
136.     }
137. }

まぁいつも通りいきなりな感じで、こう。
書き込むとUARTに文字列が出力される。で、平置きでは
4101A4FE741F8C
ってなる。で、計算してみると、

	STATUS	XDATA	YDATA	ZDATA
4101A4FE741F8C	41	01A4	FE74	1F8C
		420	65140	8076	unsigned
		420	-396	8076	signed
		105	-99	2019	2bits shift /4
		0.05126953125	-0.04833984375	0.98583984375	Scaled *(8/(2^14))

てな感じ。うまくいっていると思う。
USBコネクタ周りに90度回すと
X=0.03857421875
Y=0.931640625
Z=0.0048828125
USBコネクタ部が上空に来るように90度回すと
X=0.9970703125
Y=0.048828125
Z=-0.0390625
いいぞ！では次はBLEで飛ばしてみよう！、、、後で。
 
ところで、年の瀬だねー。2024年、支えてくれたいろんな人への感謝とともに、あと数日、できるだけ、がんばる。、、、できるだけよ。